ELT - LAB4 -  ANALISI DI CIRCUITI RESISTIVI NON LINEARI CON PSpice


----------------- es. 1 ------------------------------------------------
Caratteristica di un diodo a giunzione 
* 11.08.02
*
* Sottocircuito che descrive il diodo 
.SUBCKT JDIODE 11 12
GD 11 12 VALUE = { 1E-9*(EXP(V(11,12)/0.026) - 1)} 
.ENDS
*
* Circuito per il tracciamento della caratteristica
V1 1 0  ; generatore di prova, che verra' fatto variare con il successivo  
        ; comando .DC per tracciare la caratteristica
*  Diodo 
XD 1 0 JDIODE
*
.DC V1 -0.5 1 0.002  ; il generatore V1 viene fatto variare da -0.5V a 1.0V, a passi di 2mV
.PROBE               ; per ottenere la caratteristica, occorre visualizzare -I(V1) in
                     ; funzione di V1
.END
----------------- fine es. 1 -------------------------------------------

----------------- es. 2 ------------------------------------------------
Circuito con diodo ideale
* 11.08.02
* 
V1 1 0 10
*  Diodo ideale:
D1 1 2 MOD1
.MODEL MOD1 D(N=0.01 IS=1.E-16) ; con N=0.01 si ottiene la caratteristica di un
                                ; diodo praticamente ideale
R1 2 0 4K
R2 2 3 2K
VS 3 0 PWL(0 0 0.004 30 0.006 0 0.010 0)
.TRAN 0.01E-3 10E-3 0 1E-6  ; transitorio da 0.01ms a 10ms, memorizzato da t=0.
                            ; il passo d'integrazione e' forzato a non 
                            ; superare 1 microsecondo.
.PROBE   ; Vu e' la tensione V(2) del nodo 2
         ; Vs e' la tensione V(3) del nodo 3
.END
----------------- fine es. 2 -------------------------------------------

----------------- es. 3 ------------------------------------------------
Rivelatore di picco
* 11.08.02
* 
V1 1 0 SIN(0 1 10KHZ 0 0 0)
V2 2 0 SIN(0 1 30KHZ 0 0 0)
V3 3 0 SIN(0 1 50KHZ 0 0 0)
R1 1 4 6.37K
R2 2 4 2.12K
R3 3 4 1.27K
RF 4 5 5K
D1 5 6 MOD1
C1 6 0 1E-6
*  Amplificatore operazionale (praticamente) ideale:
EOA 5 0 0 4 10E8
*
*  Diodo ideale:
.MODEL MOD1 D(N=0.01 IS=1.E-16)
*
.TRAN 0.001E-3 0.2E-3 0 1E-7
.PROBE
.END
----------------- fine es. 3 -------------------------------------------

----------------- es. 4 ------------------------------------------------
Amplificatore logaritmico
* 11.08.02
* 
VS 1 0 pwl(0 0.001 1 0.001 1.001 .01 2 0.01 2.001 0.1 3 0.1)
RS 1 2 10K
XD 2 3 JDIODE
*  Amplificatore operazionale ideale:
EOA 3 0 0 2 10E8
* 
*  Diodo a giunzione:
.SUBCKT JDIODE 11 12
GD 11 12 VALUE = { 1E-9*(EXP(V(11,12)/0.026) - 1)} 
.ENDS JDIODE
*
.TRAN 0.01 3
.PROBE    ; Vu e' data dalla tensione V(3) del nodo 3
.END
----------------- fine es. 4 -------------------------------------------