ELT - LAB3 -  ANALISI IN REGIME SINUSOIDALE CON PSpice


----------------- es. 1 ------------------------------------------------
Risonatore reale parallelo; 
* 12.10.01
* 
IS 0 1 AC 0.001 SIN(0 0.001 1MEG 0 0 0) ; ampiezza 1mA invece di 1.41mA: i risultati 
                                        ; andranno moltiplicati per 1.41 per avere  
                                        ; le ampiezze dei segnali
RP 1 0 118.906K
C 1 0 253.303E-12
L 1 0 100E-6
*
.AC LIN 1001 985K 1015K
.TRAN 0.1U 1000U 0 1E-8
* con i valori sottostanti il transitorio e' del tutto errato
*.TRAN 1U 1000U 
.PROBE
.END
----------------- fine es. 1 -------------------------------------------

----------------- es. 2 ------------------------------------------------
Risonatore reale serie; 
* 31.5.96
* 
* Valore efficace  20 mV; le uscite saranno valori efficaci
Ve 1 0  AC 0.020
Rs 1 2 3.01
L 2 3 141e-6
C 3 0 282e-12
*
.AC LIN 1001 795K 801K
.PROBE
.END
----------------- fine es. 2 -------------------------------------------

----------------- es. 3 ------------------------------------------------
Curva di risposta in frequenza di un equalizzatore RIAA
r1 1 2 330k
r2 2 4 7.5k
r3 2 3 30k
r4 4 0 82k
c1 4 0 40e-9
c2 3 0 2e-9
vin 1 0 ac 1
.AC DEC 10 1 100e3
.probe
.end
----------------- fine es. 3 -------------------------------------------

----------------- es. 4 -------------------------------------------
Analisi di un filtro LC passa banda
* onda quadra simmetrica, di periodo 312.5us, corrispondente a 3200Hz, 
* ampiezza 1V; 3200 Hz e' la frequenza di centro banda del filtro, cui 
* corrisponde un'attenuazione di 6dB.
* Attenzione, cio' che e' attenuato di 6dB e' la fondamentale,
* che non ha ampiezza di 1V, ma un po' di piu' (provare a fare lo
* sviluppo in serie dell'onda quadra e calcolare l'ampiezza della
* fondamentale).
VI 1 0 AC 1 pulse(-1 1 0 0.1ns 0.1ns 156.25us 312.5us)
RG 1 3 75
RU 2 0 75
C1 3 0 3.37818uF
L1 3 0 735.117uH
L2 3 4 38.004586e-3
C2 4 2 65.34375nF
L3 2 0 735.117uH
C3 2 0 3.37818uF
.AC LIN 101 1.9kHz 4.6kHz 
.tran 1us 12.5ms 10ms 0.1us  ; i dati sono memorizzati solo da 12.5ms in avanti 
                             ;  (quando si e' raggiunta una condizione di regime)
.probe
.end
----------------- fine es. 4 -------------------------------------------