ELT - LAB2 -  ANALISI DI TRANSITORI CON PSpice

----------------- es. 1 ------------------------------------------------
Transitorio RC con interruttore
* Circuito:
VE 1 0 30 
R1 1 4 8e3
R2 4 0 2K
R3 4 3 800
C 3 5 250E-6
R 5 0 1.6E3
R4 1 2 12E3
S1 2 3  6 0 SMOD
.MODEL SMOD VSWITCH  ROFF=1E10
* Generatore per il comando di S1:
VS 6 0 pulse(0 2 1 1e-6 1e-6 1 100)
* Analisi:
.TRAN 0.05 5
.PROBE V(R) V(C)
.end
----------------- fine es. 1 -------------------------------------------

----------------- es. 2 ------------------------------------------------
Circuito RL con generatore sinusoidale
.param freq = 79.577            ;frequenza  corrispondente a una pulsazione di 500 rad/s
VS 1 0 SIN(0 150 {freq} 0 0 0)  ;generatore sinusoidale di  
                                ;frequenza 500/(2pi)e ampiezza 150V
R 1 2 50
L  2 0 0.2 IC=0
.TRAN 0.1E-3 50E-3 0 10E-6 UIC ;per ottenere una precisione maggiore,  
                               ;l'intervallo di integrazione e' forzato a 
                               ;non superare 10e-6 secondi
.probe i(L)
.end
----------------- fine es. 2 -------------------------------------------

----------------- es. 3 ------------------------------------------------
Cella RC-attiva: Vu coincide con V(3)
.param freq = 3000
Ve 1 0 SIN(0 0.1 {freq} 0 0 0) ; generatore sinusoidale di frequenza
                               ; 3000Hz e ampiezza 100mV
R1 1 2 1K
R4 2 3 12.2K 
C3 2 3 47nF
R2 2 7 1.5K
XOA1 0 2 3 OPAMP
R5 3 4 1.22K
C6 4 5 47nF
XOA2 0 4 5 OPAMP
R7 5 6 1.5K
R8 6 7 1.5K
XOA3 0 6 7 OPAMP
*  Amplificatore operazionale ideale:
.SUBCKT OPAMP 1 2 3
*             | | +--- morsetto d'uscita
*             | +----- morsetto -
*             +------- morsetto +
EOA 3 0 1 2 10E8 ; generatore di tensione controllato di tensione,  
                 ; con amplificazionepraticamente infinita
.ENDS
*
.tran 0.01e-3 10e-3 0 1e-6 ; il passo di integrazione e' limitato a 1e-6,
                           ; per maggiore precisione
.probe V(3)
.end
----------------- fine es. 3 -------------------------------------------

----------------- es. 4 ------------------------------------------------
Partitore compensato
* 12.10.01
*
* Caso compensato: 
.param valC2 = 10nF   ; sovracompensato: 5nF  sottocompensato: 20nF
*
VS 1 0 pulse(0 2 0 1ns 1ns 5us 10u)
R1 1 2 2kohm
C1 1 2 5nF
R2 2 0 1kohm
C2 2 0 {valC2}
* La costante di tempo nel caso compensato e' tau=10u
.STEP PARAM valC2 list  20nF  10nF  5nF
.TRAN 0.1u 100u
.PROBE
.END
----------------- fine es. 4 -------------------------------------------